OracleDB库

OracleDBLibrary 是一个用于 Robot Framework 的数据库测试库，它在内部使用了 cx_Oracle 工具。该项目托管在 GitHub 上，可以从 PyPI 找到下载。

安装

推荐的安装方式是使用pip

pip install --upgrade robotframework-oracledb-library

用法

要在机器人框架测试中使用 OracleDBLibrary，首先需要使用Library设置导入该库，就像任何其他库一样。

在使用 Robot Framework 时，通常建议编写尽可能易于理解的测试。不过，OracleDBLibrary 提供的关键字级别非常低，并且通常需要将数据源名称 (DSN) 等特定于实现的参数作为参数传递。因此，使用 Robot Framework 的高级关键字编写测试通常是一个好主意，这些关键字在内部使用 OracleDBLibrary 关键字。以下示例说明了这一点，其中 OracleDBLibrary 关键字如、ORACLE MAKEDSN和主要由更高级别的关键字（如.ORACLE CONNECTORACLE CONNECTION PINGORACLE CONNECTION CLOSECONNECT TO ORACLE DATABASE WITH SID

*** Settings ***
Library           OracleDBLibrary

*** Variables ***
${HOST}      localhost
${PORT}      1521
${SID}       ORCLCDB
${USER}      SYS
${PASSWORD}  Oradoc_db1
${MODE}      SYSDBA

*** Test Cases ***
CONNECT TO ORACLE DATABASE AND INSERT DATA
    CONNECT TO ORACLE DATABASE WITH SID
    INSERT DATA INTO ORACLE DATABASE
    DROP ORACLE DATABASE TABLE
    CLOSE ORACLE DATABASE CONNECTION AND CURSOR

*** Keywords ***
CONNECT TO ORACLE DATABASE WITH SID
    ${DSN}  ORACLE MAKEDSN  host=${HOST}  port=${PORT}  sid=${SID}
    ORACLE CONNECT  user=${USER}  password=${PASSWORD}  dsn=${DSN}  mode=${MODE}
    ${CONNECTION STATUS}  ORACLE CONNECTION PING
    SHOULD BE EQUAL  ${CONNECTION STATUS}  ${NONE}

INSERT DATA INTO ORACLE DATABASE
    ORACLE CONNECTION CURSOR
    ${FIRST TABLE ROW}   EVALUATE  (1432, 'Ahmet', 'Yalcinkaya')
    ${SECOND TABLE ROW}  EVALUATE  (1453, 'Abdullah', 'Deliogullari')
    ${THIRD TABLE ROW}   EVALUATE  (1481, 'Erim', 'Cerrahoglu')
    ORACLE CURSOR EXECUTE  CREATE TABLE persons (person_id NUMBER GENERATED BY DEFAULT AS IDENTITY, first_name VARCHAR2(50) NOT NULL, last_name VARCHAR2(50) NOT NULL, PRIMARY KEY(person_id))
    ORACLE CURSOR EXECUTE  INSERT INTO persons (person_id, first_name, last_name) VALUES ${FIRST TABLE ROW}
    ORACLE CURSOR EXECUTE  INSERT INTO persons (person_id, first_name, last_name) VALUES ${SECOND TABLE ROW}
    ORACLE CURSOR EXECUTE  INSERT INTO persons (person_id, first_name, last_name) VALUES ${THIRD TABLE ROW}
    ORACLE CONNECTION COMMIT

DROP ORACLE DATABASE TABLE
    ORACLE CURSOR EXECUTE  DROP TABLE persons
    ORACLE CONNECTION COMMIT

CLOSE ORACLE DATABASE CONNECTION AND CURSOR
    ORACLE CURSOR CLOSE
    ORACLE CONNECTION CLOSE

执照

Robot Framework 是开源软件Apache License 2.0